COWbrowse

You are looking at a material called torch

The candle material reacts to the light and blow commands.

When lit, it will light the location, but shorten over time until health is gone.

If you create some candles, the singular class becomes 'candl'. This material detects and fixes it to 'candle' when lit.

If there are more than 1 candles (using the more command), then each time it burns out, qty will be reduced and health will go back to healthmax.

Created by thorn, last updated 14 Apr 2008

Code

if target of light then torchignite;
if target of blow then torchblowout;
##torchignite:
$qty = $actor's qty;
$oneworth = $actor's worth;
divide $oneworth by $qty;
add 1 to $oneworth;
$chance = random $oneworth;
if $chance > 0 then torchignite1 else torchfizzle;
##torchfizzle:
print "Unfortunately, [$actor] won't burn.";
$material = $actor's material;
swap $material take _light_;
set $actor's material to $material;
##torchignite1:
if $actor's class == candl then fixsingular;
if $actor's qty > 1 then torchignite2 else torchignite3;
$material = $actor's material;
swap $material add _light_;
set $actor's material to $material;
set $actor's pose to 'burning';
relook $loc;
##torchignite2:
print "One of [$actor] begins to burn.";
##torchignite3:
print "[$actor] begins to burn.";
##tickloc:runsub torchburning;
##torchburning:
if $actor's material like _light_ then torchburning2;
##torchburning2:
$qty = $actor's qty;
$oneworth = $actor's worth;
divide $oneworth by $qty;
add 1 to $oneworth; // it must always be > 0;
runsub "torchreduce/$oneworth";
##torchreduce:
$health = $actor's health;
if $health < 1 then torchburnout else torchshort;
##torchshort:
if $qty > 1 then torchshort1 else torchshort2;
take 1 from $health;
set $actor's health to $health;
##torchshort1:
print "One of [$actor] seems a little dimmer...";
##torchshort2:
print "[$actor] seems a little dimmer...";
##torchburnout:
$material = $actor's material;
swap $material take _light_;
set $actor's material to $material;
set $actor's pose to 'burned out';
if $qty < 2 then torchburnout2 else torchburnout3;
take 1 from $qty;
$worth = $actor's worth;
take $oneworth from $worth;
add 1 to $worth; // since $oneworth was inflated by a penny;
set $actor's qty to $qty;
set $actor's worth to $worth;
$healthmax = $actor's healthmax;
set $actor's health to $healthmax;
##torchburnout2:
print "[$actor] burns out.";
delete $actor to 0 internals $loc;
set $actor's loc to 0;
relook $loc;
##torchburnout3:
print "One of [$actor] burns out.";
relook $loc;
##torchblowout:
$material = $actor's material;
swap $material take _light_;
set $actor's material to $material;
set $actor's pose to '';
print "[$actor] is blown out";
relook $loc;
##fixsingular:
set $actor's class to torch;