##tickloc:runsub ticked;

##ticked:
$cnt = $actor's counter;
$fromhit = $actor's slot1;
$tohit = $actor's slot2;
$weapon = $actor's slot3;
case $cnt do doinit,dodamage,dodamage,dodamage,dodamage,alldone;

##doinit:
say 'msg',"[$weapon] casts [$actor] towards [$tohit]!";
say 'msg',"[$tohit] is engulfed in flames!";
multiset $actor to "counter=1,host='$tohit',hosthow='at'";

##dodamage:
$hlth = $tohit's health;
take 2 from $hlth;
if $hlth < 0 then zeroit;
set $tohit's health to $hlth;
$t = $target;
$target = $tohit;
$verb = (chokes,coughs,gags,gasps for breath);
say 'burn',"[$tohit] $verb within [$actor]!";
$target = $t;
add 1 to $cnt;
set $actor's counter to $cnt;
if $hlth < 1 then saydead;

##zeroit:
$hlth = 0;

##saydead:
say 'msg',"[$tohit] chokes to death.";
set $actor's counter to 5;

##alldone:
say 'msg',"[$actor] vanishes.";
unhost $actor;
$charge = $actor's health;
take 1 from $charge;
if $charge > 0 then continue else gone;
multiset $actor to "host=0,hosthow='',pose='hidden',counter=0,health='$charge',loc='$weapon'";
relook $loc;
switch $actor off;

##gone:
$weapon = 0;