##tickloc:runsub ticked;

##ticked:
var $cnt to $actor's counter;
var $fromhit to $actor's slot1;
var $tohit to $actor's slot2;
case $cnt do doinit,dodamage,dodamage,dodamage,alldone;

##doinit:
say 'msg',"[$fromhit] casts [$actor] at [$tohit]!";
say 'msg',"[$tohit] is covered in ice!";
set $actor's counter to 1;
set $actor's pose to 'freezing';
set $actor's host to $tohit;
set $actor's hosthow to 'around';
relook $loc;

##dodamage:
var $hlth to $tohit's health;
take 1 from $hlth;
if $hlth < 0 then zeroit;
set $tohit's health to $hlth;
$verb = (shivers,feels a little frostbitten,feels frigid);
$obj = (coating of ice,ice covering,frozen glaze);
$t = $target;
$target = $tohit;
say 'freeze',"[$tohit] $verb from the $obj.";
$target = $t;
add 1 to $cnt;
set $actor's counter to $cnt;
if $hlth > 0 then continue else saydead;

##zeroit:
$hlth = 0;

##saydead:
say 'msg',"[$tohit] is frozen to death.";
set $actor's counter to 4;

##alldone:
say 'msg',"[$actor] thaws out";
set $actor's code to '';
set $actor's loc to $0;
unhost $actor;
set $actor's host to 0;
set $actor's hosthow to '';
set $actor's counter to 0;
clear $actor,all;
relook $loc;
switch $actor off;

##difficultdata:
$dcommand = 'cast';
$dlevel = 1;
$dreq = 2;
$dskill = 'sorcery';
$dskillcap = 10;
$dskilltip = 69431;

##failcast:
"[$init_obj]'s attempt fizzles.";